アセンブラ理解度 - lethevert is a programmer

[id:w_o:20051006:p1]
アセンブラを少しだけ理解したので、ここのコードを分析してみる。

	org 100h

まず、実行開始番地を指定。COM実行形式の実行ファイルの場合は、これを書きます。

	section .text

コードセクションの開始。セクションは、コード（.text）、データ（.data）、初期化されていないデータ（.bss）などがある。

start:
	mov	cl, 4

（中略）

	loop	tableload

CXレジスタ（２バイト）を用いたループを作成する。LOOPコマンドは、CXレジスタから１引いて０でなければラベルにジャンプする命令。

	mov	ah, 02h

後の割り込み（int 21h）時の命令を事前にahレジスタ（１バイト）にセット。
02hは、「１文字出力する」という命令。

	mov	bx, table

（中略）

table:
	dw	(26<<8)|'A'
	dw	(26<<8)|'a'
	dw	(10<<8)|'0'
	dw	(1<<8)|'_'

bxレジスタ（２バイト）にtableで宣言されたデータへのポインタをセット。
tableデータは、「２バイト×４」のデータで、上位１バイトが繰り返し回数、下位１バイトが初期値です。
※ ４バイト単位の場合はdd、２バイト単位の場合はdw、１バイト単位の場合はdb

tableload:
	mov	dx, [bx]

bxレジスタ（２バイト）が指すデータを、dxレジスタ（２バイト）に読み込む。

outstr:	
	int	21h

dlレジスタ（１バイト）のデータ（１文字）を、出力する。
dlレジスタは、dxレジスタの下位１バイト。

	inc	dx

dxレジスタ（２バイト）をインクリメントする。実質的に、dlレジスタ（１バイト）をインクリメントして、出力文字を次の文字に進めている。

	dec	dh

dhレジスタ（１バイト）をデクリメントする。dhレジスタは、dxレジスタの上位１バイトで、カウンタとして利用している。
演算結果が０になると、ZFフラグが１になる。

	jnz	outstr

ZFフラグが０（演算結果がゼロでない）であれば、outstrラベルにジャンプする。

	inc	bx
	inc	bx

bxレジスタ（２バイト）に格納されたアドレス（tableデータを指す）を２バイト分進める。

	loop	tableload

CXレジスタから、１引いて０でなければtableloadラベルにジャンプ。CXレジスタには、冒頭で４がセットされている。

ret

終了。